CheckIncrementalPlasticity.cmake

Go to the documentation of this file.

if(DEFINED EP_MESHSETS)
  file(READ "${EP_JSON_CONFIG}" input)
  string(JSON input SET "${input}" meshes 0 meshsets "${EP_MESHSETS}")
  set(EP_JSON_CONFIG "${CMAKE_CURRENT_BINARY_DIR}/incremental_plasticity.json")
  file(WRITE "${EP_JSON_CONFIG}" "${input}\n")
endif()
 
if(NOT EP_RUN_LOG)
  set(EP_RUN_LOG incremental_nullspace_plastic.log)
endif()
set(run_log "${CMAKE_CURRENT_BINARY_DIR}/${EP_RUN_LOG}")
execute_process(
  COMMAND
    "${EP_MPI_RUN}" ${EP_MPI_RUN_FLAGS} -np 1 "${EP_EXECUTABLE}"
    -json_config "${EP_JSON_CONFIG}" ${EP_EXTRA_ARGUMENTS}
  RESULT_VARIABLE run_result
  OUTPUT_FILE "${run_log}"
  ERROR_FILE "${run_log}")
 
file(READ "${run_log}" run_output)
if(NOT run_result EQUAL 0)
  message(FATAL_ERROR "Plasticity solve failed (${run_result}):\n${run_output}")
endif()
if(NOT run_output MATCHES
   "plasticity incremental optimization converged: [^\n]*plastic flow active true")
  message(FATAL_ERROR
    "Expected a converged, validated increment with nonzero plastic flow:\n"
    "${run_output}")
endif()
 
set(acceptance "${CMAKE_MATCH_0}")
if(NOT run_output MATCHES
   "Incremental optimization completed [1-9][0-9]* physical steps at time [0-9.eE+-]+")
  message(FATAL_ERROR "Plastic solve did not finish committing its physical steps:\n${run_output}")
endif()
string(REGEX MATCHALL "plasticity TAO evaluation at iteration [^\n]*"
  evaluations "${run_output}")
if(NOT evaluations)
  message(FATAL_ERROR "Plastic solve did not report objective evaluations")
endif()
list(GET evaluations -1 final_evaluation)
if(NOT final_evaluation MATCHES ", dissipation ([0-9.eE+-]+)\\‍)")
  message(FATAL_ERROR "Missing final plastic dissipation: ${final_evaluation}")
endif()
set(final_dissipation "${CMAKE_MATCH_1}")
if(NOT final_dissipation GREATER 0)
  message(FATAL_ERROR "Active plastic flow has nonpositive dissipation: ${final_evaluation}")
endif()
 
message(STATUS "${acceptance}; final dissipation ${final_dissipation}")