ModulesList.cmake

Go to the documentation of this file.

# If the basic UMs are already loaded target to um library. Otherwise, build a
# basic user modules library.
if(EXTERNAL_MODULE_SOURCE_DIRS)
 
  find_package(
     MoFEM REQUIRED HINTS ${MOFEM_DIR} ${PROJECT_BINARY_DIR} $ENV{MOFEM_DIR})  
 
  # Find modules in an external directory. If file InstalledAddModule.cmake if
  # found in the directory, it is recognized that director is module and name of
  # directory become module name.
  foreach(LOOP_DIR ${EXTERNAL_MODULE_SOURCE_DIRS})
    message(STATUS "Search module directory: " ${LOOP_DIR})
    file(
      GLOB_RECURSE EXTERNAL_INSTLLED_MODULES
      FOLLOW_SYMLINKS
      ${LOOP_DIR}/*InstalledAddModule.cmake)
    message(STATUS "Found: " ${EXTERNAL_INSTLLED_MODULES})
    set(INSTALLED_MODULES ${INSTALLED_MODULES} ${EXTERNAL_INSTLLED_MODULES})
  endforeach(LOOP_DIR)
 
else(EXTERNAL_MODULE_SOURCE_DIRS)
 
  # Find modules in a users modules source directory. If file
  # InstalledAddModule.cmake is found in the directory, it is recognized that
  # directory is module and name of directory become module name.
  file(
    GLOB_RECURSE INSTALLED_MODULES
    FOLLOW_SYMLINKS
    ${PROJECT_SOURCE_DIR}/users_modules/?*/InstalledAddModule.cmake)
 
endif(EXTERNAL_MODULE_SOURCE_DIRS)
 
# Install modules && git pull for all users modules
add_custom_target(
  update_users_modules
  COMMENT "Update all modules ..." VERBATIM)
add_custom_target(
  checkout_develop
  COMMENT "Checkout develop branch ..." VERBATIM)
add_custom_target(
  checkout_master
  COMMENT "Checkout master branch ..." VERBATIM)
 
# Recognize that module is installed
foreach(LOOP_MODULE ${INSTALLED_MODULES})
  string(REGEX REPLACE
    "/+InstalledAddModule.cmake" ""
    MODULE_DIRECTORY ${LOOP_MODULE})
  string(REGEX REPLACE
    ".*/+" ""
    MODULE_NAME ${MODULE_DIRECTORY})
  string(REGEX REPLACE "-" "_" MODULE_NAME ${MODULE_NAME}) 
  string(TOUPPER ${MODULE_NAME} MODULE_NAME)
  message(STATUS "Add definitions to the compiler command -DWITH_MODULE_${MODULE_NAME}")
  add_definitions(-DWITH_MODULE_${MODULE_NAME})
endforeach(LOOP_MODULE)
 
# Add custom tags for all modules
foreach(LOOP_MODULE ${INSTALLED_MODULES})
  # message(STATUS "${LOOP_MODULE}")
  string(REGEX REPLACE
    "/+InstalledAddModule.cmake" ""
    MODULE_DIRECTORY ${LOOP_MODULE})
  message(STATUS "Add module ... ${MODULE_DIRECTORY}")
  string(REGEX REPLACE
    ".*/+" ""
    MODULE_NAME ${MODULE_DIRECTORY}
  )
  if(
    NOT ${MODULE_NAME} MATCHES "basic_finite_elements")
    #message(STATUS "Add custom targets for ${MODULE_NAME}")
    add_custom_target(
      update_${MODULE_NAME}
      COMMAND ${GIT_EXECUTABLE} pull
      WORKING_DIRECTORY ${MODULE_DIRECTORY}
      COMMENT "Update module ... ${MODULE_NAME}" VERBATIM)
    add_dependencies(update_users_modules update_${MODULE_NAME})
    add_custom_target(
      checkout_develop_${MODULE_NAME}
      COMMAND ${GIT_EXECUTABLE} checkout develop
      WORKING_DIRECTORY ${MODULE_DIRECTORY}
      COMMENT "Checkout develop baranch for module ${MODULE_NAME}" VERBATIM)
    add_dependencies(checkout_develop checkout_develop_${MODULE_NAME})
    add_custom_target(
      checkout_master_${MODULE_NAME}
      COMMAND ${GIT_EXECUTABLE} checkout master
      WORKING_DIRECTORY ${MODULE_DIRECTORY}
      COMMENT "Checkout master baranch for module ${MODULE_NAME}" VERBATIM)
    add_dependencies(checkout_master checkout_master_${MODULE_NAME})
  endif(
    NOT ${MODULE_NAME} MATCHES "basic_finite_elements")
  # include module
  include(${LOOP_MODULE})
endforeach(LOOP_MODULE)