RunAuxiliaryCook.cmake

Go to the documentation of this file.

# Compare both accepted states of the same mesh-stress discretisation.
file(READ "${EP_INPUT}" input)
if(EP_RANKS EQUAL 1)
  string(JSON input SET "${input}" meshes 0 file_name
    "\"examples/cook_cantilever/cook.cub\"")
endif()
foreach(solver explicit condensed)
  set(run_input "${input}")
  if(solver STREQUAL "condensed")
    string(JSON run_input SET "${run_input}" petsc elastic ksp
      "{\"type\":\"fgmres\",\"rtol\":1e-12,\"atol\":1e-12}")
    string(JSON run_input SET "${run_input}" petsc elastic pc
      "{\"type\":\"fieldsplit\",\"fieldsplit_type\":\"schur\"}")
    string(JSON run_input SET "${run_input}" petsc elastic fieldsplit_0
      "{\"ksp\":{\"type\":\"preonly\"}}")
    string(JSON run_input SET "${run_input}" petsc elastic fieldsplit_1
      "{\"pc\":{\"type\":\"ksp\"},\"ksp\":{\"type\":\"preonly\",\"pc\":{\"type\":\"lu\",\"factor_mat_solver_type\":\"mumps\"},\"mat_mumps_icntl_20\":0,\"mat_mumps_icntl_14\":800}}")
  endif()
  file(WRITE "${solver}.json" "${run_input}\n")
  file(REMOVE "${solver}.vec" "${solver}.vec.info")
  execute_process(
    COMMAND "${EP_MPI_RUN}" ${EP_MPI_RUN_FLAGS} -np ${EP_RANKS}
      "${EP_EXECUTABLE}" -json_config "${solver}.json"
      -elastic_snes_view_solution "binary:${solver}.vec::append"
    OUTPUT_FILE "${solver}.log" ERROR_FILE "${solver}.err"
    RESULT_VARIABLE result)
  if(NOT result EQUAL 0)
    message(FATAL_ERROR "Auxiliary Cook ${solver} failed: ${result}; see ${solver}.log/.err")
  endif()
endforeach()
execute_process(
  COMMAND "${EP_MPI_RUN}" ${EP_MPI_RUN_FLAGS} -np ${EP_RANKS}
    "${EP_COMPARE}" -compare_left explicit.vec -compare_right condensed.vec
    -compare_count 2 -compare_tolerance 1e-10
  RESULT_VARIABLE result)
if(NOT result EQUAL 0)
  message(FATAL_ERROR "Explicit and condensed solution vectors differ: ${result}")
endif()