RunAuxiliaryPatch.cmake

Go to the documentation of this file.

# Each patch test owns its generated mesh and output.
execute_process(
  COMMAND "${EP_MPI_RUN}" ${EP_MPI_RUN_FLAGS} -np 1 "${EP_PATCH}"
    -json_config auxiliary_logarithmic_stress_patch_prepare.json
  OUTPUT_FILE prepare.log ERROR_FILE prepare.err RESULT_VARIABLE result)
if(NOT result EQUAL 0)
  message(FATAL_ERROR "Patch mesh preparation failed: ${result}")
endif()
set(mesh auxiliary_logarithmic_stress_patch.h5m)
if(EP_RANKS GREATER 1)
  execute_process(
    COMMAND "${EP_MPI_RUN}" ${EP_MPI_RUN_FLAGS} -np 1 "${EP_PARTITION}"
      -file_name "${mesh}" -output_file auxiliary_logarithmic_stress_patch_2p.h5m
      -nparts 2
    OUTPUT_FILE partition.log ERROR_FILE partition.err RESULT_VARIABLE result)
  if(NOT result EQUAL 0)
    message(FATAL_ERROR "Patch mesh partition failed: ${result}")
  endif()
  set(mesh auxiliary_logarithmic_stress_patch_2p.h5m)
endif()
execute_process(
  COMMAND "${EP_MPI_RUN}" ${EP_MPI_RUN_FLAGS} -np ${EP_RANKS} "${EP_PATCH}"
    -json_config auxiliary_logarithmic_stress_patch_atom.json -file_name "${mesh}"
    -analytical_expr_file "${EP_PATCH_PYTHON}"
    -elastic_mat_mumps_icntl_20 0 -elastic_mat_mumps_icntl_14 800
  RESULT_VARIABLE result)
if(NOT result EQUAL 0)
  message(FATAL_ERROR "Homogeneous auxiliary patch failed: ${result}")
endif()