umat_small_strain.for

Go to the documentation of this file.

!**********************************************************************
!  Small strain isotropic elasticity UMAT
!
!  props(1) - Young's modulus
!  props(2) - Poisson ratio
!**********************************************************************
 
      subroutine umat(stress,statev,ddsdde,sse,spd,scd,
     + rpl,ddsddt,drplde,drpldt,
     + stran,dstran,time,dtime,temp,dtemp,predef,dpred,cmname,
     + ndi,nshr,ntens,nstatv,props,nprops,coords,drot,pnewdt,
     + celent,dfgrd0,dfgrd1,noel,npt,layer,kspt,kstep,kinc)
 
      implicit real*8(a-h,o-z)
 
      dimension stress(ntens),statev(nstatv),
     + ddsdde(ntens,ntens),ddsddt(ntens),drplde(ntens),
     + stran(ntens),dstran(ntens),time(2),predef(1),dpred(1),
     + props(nprops),coords(3),drot(3,3),dfgrd0(3,3),dfgrd1(3,3)
 
      character*80 cmname
 
      integer i,j
 
      real*8 eye(3,3),eps(3,3),sigma(3,3)
      real*8 young,nu,mu,kappa,lambda,treps
 
 
      real*8 zero,one,two,half,three,third
      parameter(zero=0.d0,one=1.d0,two=2.d0,half=0.5d0,three=3.d0,
     +     third=1.d0/3.d0)
 
      eye = zero
      do i=1,3
         eye(i,i) = one
      enddo
 
      young = props(1)
      nu = props(2)
      mu = young/(two*(one+nu))
      kappa = young/(three*(one-two*nu))
      lambda = kappa - two*third*mu
 
      eps = half*(dfgrd1 + transpose(dfgrd1)) - eye
      treps = eps(1,1) + eps(2,2) + eps(3,3)
      sigma = two*mu*eps + lambda*treps*eye
 
      stress(1) = sigma(1,1)
      stress(2) = sigma(2,2)
      stress(3) = sigma(3,3)
      stress(4) = sigma(1,2)
      if(ntens.eq.6) then
         stress(5) = sigma(1,3)
         stress(6) = sigma(2,3)
      endif
 
      ddsdde = zero
 
      do i=1,3
         ddsdde(i,i) = lambda + two*mu
      enddo
      do i=1,3
         do j=1,3
            if(i.ne.j) ddsdde(i,j) = lambda
         enddo
      enddo
      do i=4,ntens
         ddsdde(i,i) = mu
      enddo
 
      return
      end subroutine umat
 
***********************************************************************